AppleScript for sending stuff to Xpenser with voice response…

Feeds:: Posts; Comments

« Understanding iOS 4 Backgrounding and Delegate Messaging

AppleScript for sending stuff to Xpenser with voice response…

December 12, 2010 by binduwavell

Open the AppleScript Editor on your Mac, paste this in to a new script:

property theUsername : "your username"
property thePassword : "your password"
property theURL : "https://www.xpenser.com/api/v1.0/expense/"
property theQueryTimeout : 10
property theDefaultQuery : "Lunch 12.14 ModMarket with Marcus #clientX"

on postExpense(theQuery)
    set XpenserUpdate to "/usr/bin/curl -s -S -m " & theQueryTimeout & ¬
        " -u " & quoted form of (theUsername & ":" & thePassword) & ¬
        " -d " & quoted form of ("q=" & theQuery) & ¬
        " " & quoted form of theURL
    set XpenserResponse to do shell script XpenserUpdate
    if XpenserResponse contains "\"status\": 1" then
        return "Your expense was saved."
    else
        return "There was a problem saving your expense!"
    end if
end postExpense

set theResult to display dialog "Add A New Expense" default answer theDefaultQuery

set theQuery to text returned of theResult
set theButton to button returned of theResult
if theButton is equal to "OK" and theQuery is not equal to theDefaultQuery then
    set theResponse to postExpense(theQuery)
    say theResponse
else
    -- do nothing
end if

Then update your username and password and save as an application in your applications folder (I called it SendToXpenser).

Now you can type apple-space to open Spotlight type SendToXpenser and press return.

You are prompted for quick entry text and you get voice confirmation if the expense was added or not.

Posted in main | Tagged Apple, applescript, commandline, development, lifehacker, osx, software, technology, tip, xpenser | 9 Comments

9 Responses

on December 13, 2010 at 9:41 am | Reply Bindu Wavell

If you want to launch this with a keyboard shortcut, you can create a service with automator. Setup no input and use the run applescript action to run this (remember to update your username and password.) Then in System Preferences -> Keyboard you can assign a keyboard shortcut to this service.
- on January 22, 2011 at 2:06 pm | Reply acray
  
  I’m not sure whether placing the content of the script directly in the service (Automator) would work for the growl notification version I posted below…
  
  But what does work is saving the script as an Application (via the original instructions above) and then using the following script in the service (Automator)
```
on run {input, parameters}

	do shell script "open /Applications/SendToExpenser.app"

	return input
end run
```
  Even if you don’t use the Growl version, it’d make it a bit easier to modify the AppleScript in the future. E.G. When you change your password.
on December 13, 2010 at 12:34 pm | Reply Even Easier OS X Expense Tracking With Xpenser - Xpenser Blog

[...] (creator of the Fresh Xpense Capture iPhone app) has come up with another fantastic little helper: an OS X app that allows very simple expense capture, with voice [...]
on January 12, 2011 at 1:17 pm | Reply Joel

Thank you. This is a huge help!

Is there any chance you might be able to add the ability to drag a file to the applescipt icon and it would upload the receipt along with the query string?
- on January 21, 2011 at 3:21 pm | Reply binduwavell
  
  I’m certain that is possible. I don’t currently have time to work on this. Hope someone else will stop by and do it. :) In any case I’ll add it to my possible future project list.

on January 21, 2011 at 1:59 am | Reply

acray

I created a variation of your script that sends a Growl alert rather than saying the response. Note: Unless you modify the script, you MUST save it as SendToExpenser

property theUsername : "your username"
property thePassword : "your password"
property theURL : "https://www.xpenser.com/api/v1.0/expense/"
property theQueryTimeout : 10
property theDefaultQuery : "Lunch 12.14 ModMarket with Marcus #clientX"

on postExpense(theQuery)
	set XpenserUpdate to "/usr/bin/curl -s -S -m " &amp; theQueryTimeout &amp; ¬
		" -u " &amp; quoted form of (theUsername &amp; ":" &amp; thePassword) &amp; ¬
		" -d " &amp; quoted form of ("q=" &amp; theQuery) &amp; ¬
		" " &amp; quoted form of theURL
	set XpenserResponse to do shell script XpenserUpdate
	if XpenserResponse contains "\"status\": 1" then
		return "Sucess"
	else
		return "Error"
	end if
end postExpense

on sendGrowl(theResponse)
	tell application "GrowlHelperApp"
		set the allNotificationsList to ¬
			{"Sucess", "Error"}
		set the enabledNotificationsList to ¬
			{"Sucess", "Error"}

		register as application ¬
			"SendToXpenser" all notifications allNotificationsList ¬
			default notifications enabledNotificationsList ¬
			icon of application "Script Editor"

		if theResponse is equal to "Sucess" then
			notify with name ¬
				"Sucess" title ¬
				"Xpenser, Yay!" description ¬
				"Go Go Xpenser Gadget" application name ¬
				"SendToXpenser"
		else
			notify with name ¬
				"Error" title ¬
				"Xpenser, Nay!" description ¬
				"There be Xpenser Dragons" application name ¬
				"SendToXpenser"
		end if
	end tell
end sendGrowl

set theResult to display dialog "Add A New Expense" default answer theDefaultQuery

set theQuery to text returned of theResult
set theButton to button returned of theResult
if theButton is equal to "OK" and theQuery is not equal to theDefaultQuery then
	set theResponse to postExpense(theQuery)
	--say theResponse
	sendGrowl(theResponse)
else
	-- do nothing
end if

on January 21, 2011 at 3:23 pm | Reply binduwavell

Cool idea, thanks for sharing!
on January 24, 2011 at 10:54 am | Reply acray

There were some copy and paste issues. The code above needs a bit of clean up. E.G. & needs to be &, line 3 should be:
```
property theURL : "https://www.xpenser.com/api/v1.0/expense/"
```
- on January 24, 2011 at 10:57 am acray
  
  Foiled again… “& amp;” should just be &. And the anchor tag needs to be stripped out of the theURL.

Comments RSS

Techno Bliss

Ramblings on technology and life